Skripte XAMPP-CMSOD

Backup & Restore - mit dem XAMPP-CMSOD, meiner Entwicklungsumgebung

Als Entwickler des CMSOD-Zertifikatssystems habe ich spezielle Backup/Restore Technik (Batchdateien, Skripte) im Ordner C:\xampp-cmsod\__backups bereitgestellt.

Diese vorbereiteten Skripte sind zum Sichern von Prüfungen im Zertifikatssystem „CMS Online Designer (CMSOD - VHS)“ gedacht.

Sie eignen sich aber natürlich auch für die lokalen XAMPP-Projektsicherungen (wie „WordPress Montag“).

Wichtig

Die Skripte (Batchdateien) nutzen die grundsätzlichen Techniken zum Sichern von Ordnern und Datenbanktabellen. Die Skripte eignen sich so aber nur für die XAMPP-CMSOD-Testumgebungen.

Der Ordner C:\xampp-cmsod\__backups enthält auch eine Anleitung zum

• Nutzen der Sicherungsskripte (Batchdateien .bat ) und zum

• Wiederherstellen mit dem restore.bat-Skript.

Für eigene Projektsicherungen muss man nur eine Batchdatei kopieren und ein paar Bezeichner austauschen!

Hinweis

Die Skripte werden aktuell überarbeitet: flexibler, interaktiv, vielleicht auch PowerShell!

Hier mal eine funktionsfähige Basisversion für das WordPress Projekt „WordPress Seminar“:

@echo off
SETLOCAL

rem ----Begrüßung -----------------------------------
echo **********************************************
echo * 1-click Sicherung CMSOD                    *
echo * bitte einfach den Anweisungen folgen...    *
echo **********************************************
echo *                                            *

rem ----Prüfungsteilnehmer einlesen------------------
echo **********************************************
echo * Bitte Benutzernamen in Form                *
echo * Nachname-Vorname                           *
echo **********************************************
echo * eingeben:                                  *
set /p Benutzer=

rem ----EINSTELLUNGEN--------------------------------
rem Ordner immer ohne abschließenden \ Backslash
rem Hauptordner für Backups:
set "Backups=c:\xampp-cmsod\__backups"
rem Arbeitsverzeichnis für 7-Zip Portable:
set "SevenZipPath=C:\xampp-cmsod\_tools\_portable\PortableApps\7-ZipPortable\App\7-Zip"
rem Hauptverzeichnis MySQL des XAMPP-CMSOD:
set "MySQLPath=C:\xampp-cmsod\mysql"
rem Hauptordner WWW bzw. htdocs bei XAMPP-CMSOD:
set "WWWhtdocsOrdnerPath=C:\xampp-cmsod\htdocs"
rem Zugangsdaten zur DB MySQL des XAMPP-CMSOD:
set "MySQLUser=root"
set "MySQLPwd=NULL"


rem Ordner für die zu erstellende Sicherung:
rem Hauptordner:
set "WWWhtdocsHauptordner=wordpress"
rem set "WWWhtdocsHauptordner=mywordpress"
rem Detaillordner:
set "WWWhtdocsOrdner=wordpress-seminar"
rem set "WWWhtdocsOrdner=wordpress-projekt"
rem DB für die zu erstellende Sicherung:
set "MySQLDB=wordpress_seminar"
rem set "MySQLDB=wordpress_projekt"


rem -------------------------------------------------
rem Sicherungsdatum erstellen:
set "BackupDate=%date:~-4%%date:~-7,2%%date:~-10,2%"
rem set "BackupTime=%time:~-11,2%%time:~-8,2%%time:~-5,2%"

rem set "BackupFile=%BackupDate%_%BackupTime%.sql"
rem SQL-Dateinamen zuweisen: Benuter_DB_Datum.sql
set "BackupFile=%Benutzer%_%MySQLDB%_%BackupDate%.sql"

rem in Arbeitsverzeichnis des MySQL wechseln:
cd %MySQLPath%\bin

echo Datenbank-Dump wird erstellt... [Datenbank: %MySQLDB%]
echo beim Passwort bitte einfach Return drücken (leeres Kennwort)

mysqldump -u%MySQLUser% --add-drop-database -p --databases %MySQLDB% > "%Backups%\%BackupFile%"

rem in WWW/htdocs Hauptordner:
rem cd %WWWhtdocsOrdnerPath%

rem mit 7-Zip Ordnerarchiv erstellen: Benutzer_Ordner_Datum.zip:
%SevenZipPath%\7z a %Backups%\%Benutzer%_%WWWhtdocsOrdner%_%BackupDate%.zip %WWWhtdocsOrdnerPath%\%WWWhtdocsHauptordner%\%WWWhtdocsOrdner%
rem mit 7-Zip SQL-Dump in Ordnerarchiv packen:
%SevenZipPath%\7z u %Backups%\%Benutzer%_%WWWhtdocsOrdner%_%BackupDate%.zip %Backups%\%BackupFile%
rem MySQL-Dump löschen:
del %Backups%\%BackupFile%

echo **********************************************
echo * Bitte checken Sie das erstellte Archiv     *
echo * Bitte sichern Sie das erstellte Archiv     *                           
echo * Gesamtarchiv: %Benutzer%_%WWWhtdocsOrdner%_%BackupDate%.zip                             
echo **********************************************

pause Ende der Sicherung mit Tastendruck - Danke ...

Diese Basisversion einer Sicherungs-Batchdatei muss nur kopiert werden und dann müssen die hervorgehobenen Zeilen (36, 39, 42) mit Ihren gewünschten Infos zu Ihrem XAMPP-CMSOD Webprojekt ausgetauscht werden.

Eine beispielhafte Sicherung (Backup) und Wiederherstellung (Restore) zeigen die folgenden Anleitungen (Screenshots).

Backup Projekt WordPress Seminar

Und hier folgt die entsprechende Wiederherstellung. Im Idealfall sind die Zielordner und die Datenbank für die Wiederherstellung leer.

Restore Projekt WordPress Seminar

Und dann gibt es natürlich noch die Master-Sicherung der gesamten XAMPP-Installation für den Umzug auf andere (Windows-)Testrechner.